112 lines
8.5 KiB
Plaintext
112 lines
8.5 KiB
Plaintext
//+------------------------------------------------------------------+
|
|
//| WMA.mq5 |
|
|
//| Copyright 2018, MetaQuotes Software Corp. |
|
|
//| https://mql5.com |
|
|
//+------------------------------------------------------------------+
|
|
#property copyright "Copyright 2018, MetaQuotes Software Corp."
|
|
#property link "https://mql5.com"
|
|
#property version "1.00"
|
|
#property description "Wilder's smoothing average"
|
|
#property indicator_chart_window
|
|
#property indicator_buffers 3
|
|
#property indicator_plots 1
|
|
//--- plot WMA
|
|
#property indicator_label1 "WMA"
|
|
#property indicator_type1 DRAW_LINE
|
|
#property indicator_color1 clrRed
|
|
#property indicator_style1 STYLE_SOLID
|
|
#property indicator_width1 1
|
|
//--- input parameters
|
|
input uint InpPeriod = 20; // Period
|
|
input ENUM_APPLIED_PRICE InpAppliedPrice = PRICE_CLOSE; // Applied price
|
|
//--- indicator buffers
|
|
double BufferWMA[];
|
|
double BufferMA1[];
|
|
double BufferMAP[];
|
|
//--- global variables
|
|
double k;
|
|
int period;
|
|
int handle_ma1;
|
|
int handle_maP;
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator initialization function |
|
|
//+------------------------------------------------------------------+
|
|
int OnInit()
|
|
{
|
|
//--- set global variables
|
|
period=int(InpPeriod<1 ? 1 : InpPeriod);
|
|
k=1.0/(double)period;
|
|
//--- indicator buffers mapping
|
|
SetIndexBuffer(0,BufferWMA,INDICATOR_DATA);
|
|
SetIndexBuffer(1,BufferMA1,INDICATOR_CALCULATIONS);
|
|
SetIndexBuffer(2,BufferMAP,INDICATOR_CALCULATIONS);
|
|
//--- setting indicator parameters
|
|
IndicatorSetString(INDICATOR_SHORTNAME,"Wilders smoothing average ("+(string)period+")");
|
|
IndicatorSetInteger(INDICATOR_DIGITS,Digits());
|
|
//--- setting buffer arrays as timeseries
|
|
ArraySetAsSeries(BufferWMA,true);
|
|
ArraySetAsSeries(BufferMA1,true);
|
|
ArraySetAsSeries(BufferMAP,true);
|
|
//--- create MA's handles
|
|
ResetLastError();
|
|
handle_maP=iMA(NULL,PERIOD_CURRENT,period,0,MODE_SMA,InpAppliedPrice);
|
|
if(handle_maP==INVALID_HANDLE)
|
|
{
|
|
Print("The iMA(",(string)period,") object was not created: Error ",GetLastError());
|
|
return INIT_FAILED;
|
|
}
|
|
handle_ma1=iMA(NULL,PERIOD_CURRENT,1,0,MODE_SMA,InpAppliedPrice);
|
|
if(handle_ma1==INVALID_HANDLE)
|
|
{
|
|
Print("The iMA(1) object was not created: Error ",GetLastError());
|
|
return INIT_FAILED;
|
|
}
|
|
//---
|
|
return(INIT_SUCCEEDED);
|
|
}
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator iteration function |
|
|
//+------------------------------------------------------------------+
|
|
int OnCalculate(const int rates_total,
|
|
const int prev_calculated,
|
|
const datetime &time[],
|
|
const double &open[],
|
|
const double &high[],
|
|
const double &low[],
|
|
const double &close[],
|
|
const long &tick_volume[],
|
|
const long &volume[],
|
|
const int &spread[])
|
|
{
|
|
//--- Проверка и расчёт количества просчитываемых баров
|
|
if(rates_total<fmax(period,4)) return 0;
|
|
//--- Проверка и расчёт количества просчитываемых баров
|
|
int limit=rates_total-prev_calculated;
|
|
if(limit>1)
|
|
{
|
|
limit=rates_total-period-2;
|
|
ArrayInitialize(BufferWMA,EMPTY_VALUE);
|
|
ArrayInitialize(BufferMA1,0);
|
|
ArrayInitialize(BufferMAP,0);
|
|
}
|
|
//--- Подготовка данных
|
|
int count=(limit>1 ? rates_total : 1),copied=0;
|
|
copied=CopyBuffer(handle_ma1,0,0,count,BufferMA1);
|
|
if(copied!=count) return 0;
|
|
copied=CopyBuffer(handle_maP,0,0,count,BufferMAP);
|
|
if(copied!=count) return 0;
|
|
|
|
//--- Расчёт индикатора
|
|
for(int i=limit; i>=0 && !IsStopped(); i--)
|
|
{
|
|
if(i==rates_total-period-2)
|
|
BufferWMA[i]=BufferMAP[i];
|
|
else
|
|
BufferWMA[i]=(BufferMA1[i]-BufferWMA[i+1])*k+BufferWMA[i+1];
|
|
}
|
|
|
|
//--- return value of prev_calculated for next call
|
|
return(rates_total);
|
|
}
|
|
//+------------------------------------------------------------------+
|