/////////////////////////////////////////////////////////////
//
// SaherElm IT Center MQL5 Trend Volume Detector Oscillator
// ---------------------------------------------------------
// Name: XTDV
// Description: trend detecting based on volumes in both sides ...
//
//
// Maintainer:
// ------------
// Hadi Khazaee Asl (hadi_khazaee_asl@yahoo.com)
//
//////////////////////////////////////////////////////
//
// Global Properties ...
#property copyright "Copyright 2023, SaherElm IT Center"
#property link "https://saherelm.ir"
#property version "1.00"
#property description "SaherElm XTDV Oscillator"
#property strict

//
// START Constants ...
//
#define ShortName "XTDV"
//
// END Constants ...
//

//
// START Inputs ...
//
input int length = 14; // Market Length
//
// END Inputs ...
//

//
// Includes Logging Library ...
#include "../Libraries/x-saherelm.log.lib.mq5";

//
// START Buffers ...
//
#property indicator_separate_window

//
#property indicator_buffers 2
#property indicator_plots 2

//
#define bullishVolumeBufferIndex 0
#define bearishVolumeBufferIndex 1

//
double bullishVolumeBuffer[];
double bearishVolumeBuffer[];

#property indicator_label1 "XBullVolume"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrAqua
#property indicator_style1 STYLE_DOT
#property indicator_width1 1

#property indicator_label2 "XBearVolume"
#property indicator_type2 DRAW_LINE
#property indicator_color2 clrMagenta
#property indicator_style2 STYLE_DOT
#property indicator_width2 1
//
// END Buffers ...
//

//
// START Global Definitions: Variables, Properties and etc ...
//
ulong xtdBullishCandleVolumes = 0;
ulong xtdBearishCandleVolumes = 0;
//
// END Global Definitions: Variables, Properties and etc ...
//

//
// START Event Handlers ...
//
//
// Initialization ...
int OnInit()
{
    //
    // Validate Inputs ...
    if (!ValidateInputs())
    {
        return INIT_PARAMETERS_INCORRECT;
    }

    //
    logTag = ShortName;

    //
    // Define Index Buffers ...
    DefineBuffers();

    //
    // Set Indicator ShortName ...
    SetIndicatorName();

    //
    // Init Succeed ...
    return INIT_SUCCEEDED;
}

//
// DeInitialization ...
void OnDeinit(const int reason)
{
    //
    // REASON_PROGRAM 0 The EA has stopped working calling the ExpertRemove() function
    // REASON_REMOVE 1 Program removed from a chart
    // REASON_RECOMPILE 2 Program recompiled
    // REASON_CHARTCHANGE 3 A symbol or a chart period is changed
    // REASON_CHARTCLOSE 4 Chart closed
    // REASON_PARAMETERS 5 Inputs changed by a user
    // REASON_ACCOUNT 6 Another account has been activated or reconnection to the trade server has occurred due to changes in the account settings
    // REASON_TEMPLATE 7 Another chart template applied
    // REASON_INITFAILED 8 The OnInit() handler returned a non-zero value
    // REASON_CLOSE 9 Terminal closed

    //
    // Here we can handle De Initialization Reasons ...
}

//
// Calculations ...
//
// Calculating what we want ...
int OnCalculate(
    //
    // total Candles on chart ...
    const int rates_total,
    //
    // total calculated Candles on charts ...
    const int prev_calculated,
    //
    // history of Candles Open Time ...
    const datetime &time[],
    //
    // history of Candles Open Price ...
    const double &open[],
    //
    // history of Candles High Price ...
    const double &high[],
    //
    // history of Candles Low Price ...
    const double &low[],
    //
    // history of Candles Close Price ...
    const double &close[],
    //
    // history of Tick Volumes on Candle ...
    const long &tick_volume[],
    //
    // history of Trade Volumes ...
    const long &volume[],
    //
    // history of Candles Spread Price ...
    const int &spread[])
{
    //
    // Prepare Buffers ...
    ArraySetAsSeries(time, true);
    ArraySetAsSeries(open, true);
    ArraySetAsSeries(high, true);
    ArraySetAsSeries(low, true);
    ArraySetAsSeries(close, true);
    ArraySetAsSeries(tick_volume, true);
    ArraySetAsSeries(volume, true);
    ArraySetAsSeries(spread, true);

    //
    // this counts Available Bars ...
    int limit;

    //
    // because in some cases we may have more than one input for
    // calculation and we must prevent any calculation
    // untill we pass the biggest input length, here we get max Input length
    // and then wait until pass it ...
    int maxLength = MathMax(0, length);

    //
    limit = prev_calculated < maxLength ? rates_total - (maxLength + 1) : rates_total - prev_calculated;

    //
    // Main Loop ...
    for (int i = limit; i >= 0 && !IsStopped(); i--)
    {
        //
        CalculateBuffers(i, close);
    }

    //
    return rates_total;
}
//
// END Event Handlers ...
//

//
// START Functions ...
//
//
// Validate Input Args for Initialization ...
bool ValidateInputs()
{
    //
    bool result = false;

    //
    // Validate Args ...
    if (length >= 5)
    {
        result = true;
    }

    //
    return result;
}

//
// Define Indexes and Styles ...
void DefineBuffers()
{
    //
    string bullishVolumeBufferLabel = "BullVol " + "(" + (string)length + ")";
    string bearishVolumeBufferLabel = "BearVol " + "(" + (string)length + ")";

    //
    // Bullish Volume Buffer ...
    ArraySetAsSeries(bullishVolumeBuffer, true);
    SetIndexBuffer(bullishVolumeBufferIndex, bullishVolumeBuffer, INDICATOR_DATA);
    PlotIndexSetInteger(bullishVolumeBufferIndex, PLOT_DRAW_BEGIN, length * 2);
    PlotIndexSetString(bullishVolumeBufferIndex, PLOT_LABEL, bullishVolumeBufferLabel);

    //
    // Bearish Volume Buffer ...
    ArraySetAsSeries(bearishVolumeBuffer, true);
    SetIndexBuffer(bearishVolumeBufferIndex, bearishVolumeBuffer, INDICATOR_DATA);
    PlotIndexSetInteger(bearishVolumeBufferIndex, PLOT_DRAW_BEGIN, length * 2);
    PlotIndexSetString(bearishVolumeBufferIndex, PLOT_LABEL, bearishVolumeBufferLabel);
}

//
// Set Indicator Short Name and also we can define Buffers Labels ...
void SetIndicatorName()
{
    //
    string indicatorShortName = "";
    StringConcatenate(indicatorShortName, ShortName, " ", "( ", length, " )");

    //
    IndicatorSetString(INDICATOR_SHORTNAME, indicatorShortName);
}

//
// Calculate Buffers ...
void CalculateBuffers(
    int bar_index,
    const double &close[])
{
    //
    // Reset Global Counters ...
    xtdBullishCandleVolumes = 0;
    xtdBearishCandleVolumes = 0;

    //
    // Loop through Closes ...
    for (int i = bar_index; i <= bar_index + length; i++)
    {
        for (int j = i + 1; j <= bar_index + length; j++)
        {
            //
            if (close[i] > close[j])
            {
                xtdBullishCandleVolumes += iVolume(_Symbol, _Period, i);
            }

            //
            if (close[i] < close[j])
            {
                xtdBearishCandleVolumes += iVolume(_Symbol, _Period, i);
            }
        }
    }

    //
    // Bullish Volume Buffer ...
    bullishVolumeBuffer[bar_index] = (double)xtdBullishCandleVolumes;

    //
    // Bearish Trend Buffer ...
    bearishVolumeBuffer[bar_index] = (double)xtdBearishCandleVolumes;
}
//
// END Functions ...
//