///////////////////////////////////////////////////////
//
// SaherElm IT Center MQL5 XLH Indicator
// ---------------------------------------------
// Name: XLH
// Description: Moving Average Indicator
// Market Analysor ...
//
//
// Maintainer:
// ------------
// Hadi Khazaee Asl (hadi_khazaee_asl@yahoo.com)
//
//////////////////////////////////////////////////////
//
// Global Properties ...
#property copyright "Copyright 2023, SaherElm IT Center"
#property link "https://saherelm.ir"
#property version "1.00"
#property description "SaherElm XLH Indicator"
#property strict

//
// START Constants ...
//
#define ShortName "XLH"
//
// END Constants ...
//

//
// START Inputs ...
//
input int length = 14;                    // Length
input ENUM_SERIESMODE hhMode = MODE_HIGH; // Highest High Calculation Method
input ENUM_SERIESMODE llMode = MODE_LOW;  // Lowest Low Calculation Method
//
// END Inputs ...
//

//
// Includes Logging Library ...
#include "../Libraries/x-saherelm.log.lib.mq5";

//
// Includes Common Library ...
#include "../Libraries/x-saherelm.common.lib.mq5";

//
// START Buffers ...
//
#property indicator_chart_window

//
#property indicator_buffers 3
#property indicator_plots 3

//
// HH Buffer ...
#define hhBufferIndex 0

//
double hhBuffer[];

//
#property indicator_label1 "XLH HH"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrAqua
#property indicator_style1 STYLE_DOT
#property indicator_width1 1

//
// LL Buffer ...
#define llBufferIndex 1

//
double llBuffer[];

//
#property indicator_label2 "XLH LL"
#property indicator_type2 DRAW_LINE
#property indicator_color2 clrFuchsia
#property indicator_style2 STYLE_DOT
#property indicator_width2 1

//
// Signal Buffer ...
#define signalBufferIndex 2

//
double signalBuffer[];

//
#property indicator_label3 "XLH S"
#property indicator_type3 DRAW_LINE
#property indicator_color3 clrGold
#property indicator_style3 STYLE_DOT
#property indicator_width3 1
//
// END Buffers ...
//

//
// START Global Definitions: Variables, Properties and etc ...
//
//
// END Global Definitions: Variables, Properties and etc ...
//

//
// START Event Handlers ...
//
//
// Initialization ...
int OnInit()
{
    //
    // Validate Inputs ...
    if (!ValidateInputs())
    {
        return INIT_PARAMETERS_INCORRECT;
    }

    //
    logTag = ShortName;

    //
    // Define Index Buffers ...
    DefineBuffers();

    //
    // Set Indicator ShortName ...
    SetIndicatorName();

    //
    // Init Succeed ...
    return INIT_SUCCEEDED;
}

//
// DeInitialization ...
void OnDeinit(const int reason)
{
    //
    // REASON_PROGRAM 0 The EA has stopped working calling the ExpertRemove() function
    // REASON_REMOVE 1 Program removed from a chart
    // REASON_RECOMPILE 2 Program recompiled
    // REASON_CHARTCHANGE 3 A symbol or a chart period is changed
    // REASON_CHARTCLOSE 4 Chart closed
    // REASON_PARAMETERS 5 Inputs changed by a user
    // REASON_ACCOUNT 6 Another account has been activated or reconnection to the trade server has occurred due to changes in the account settings
    // REASON_TEMPLATE 7 Another chart template applied
    // REASON_INITFAILED 8 The OnInit() handler returned a non-zero value
    // REASON_CLOSE 9 Terminal closed

    //
    // Here we can handle De Initialization Reasons ...
}

//
// Calculations ...
//
// Calculating what we want ...
int OnCalculate(
    //
    // total Candles on chart ...
    const int rates_total,
    //
    // total calculated Candles on charts ...
    const int prev_calculated,
    //
    // history of Candles Open Time ...
    const datetime &time[],
    //
    // history of Candles Open Price ...
    const double &open[],
    //
    // history of Candles High Price ...
    const double &high[],
    //
    // history of Candles Low Price ...
    const double &low[],
    //
    // history of Candles Close Price ...
    const double &close[],
    //
    // history of Tick Volumes on Candle ...
    const long &tick_volume[],
    //
    // history of Trade Volumes ...
    const long &volume[],
    //
    // history of Candles Spread Price ...
    const int &spread[])
{
    //
    // Prepare Buffers ...
    ArraySetAsSeries(time, true);
    ArraySetAsSeries(open, true);
    ArraySetAsSeries(high, true);
    ArraySetAsSeries(low, true);
    ArraySetAsSeries(close, true);
    ArraySetAsSeries(tick_volume, true);
    ArraySetAsSeries(volume, true);
    ArraySetAsSeries(spread, true);

    //
    // this counts Available Bars ...
    int limit;

    //
    // because in some cases we may have more than one input for
    // calculation and we must prevent any calculation
    // untill we pass the biggest input length, here we get max Input length
    // and then wait until pass it ...
    int maxLength = MathMax(0, length);

    //
    limit = (prev_calculated > rates_total || prev_calculated <= 0) ? rates_total : (rates_total - prev_calculated) + 1;

    //
    // Main Loop ...
    for (int i = limit - 1; i >= 0 && !IsStopped(); i--)
    {
        //
        CalculateBuffers(i);
    }

    //
    return rates_total;
}
//
// END Event Handlers ...
//

//
// START Functions ...
//
//
// Validate Input Args for Initialization ...
bool ValidateInputs()
{
    //
    bool result = false;

    //
    // Validate Args ...
    if (length >= 2)
    {
        result = true;
    }

    //
    return result;
}

//
// Define Indexes and Styles ...
void DefineBuffers()
{
    //
    // HH Buffer ...
    string hhBufferLabel = ShortName + " HH " + "(" + (string)length + ")";
    ArraySetAsSeries(hhBuffer, true);
    SetIndexBuffer(hhBufferIndex, hhBuffer, INDICATOR_DATA);
    PlotIndexSetInteger(hhBufferIndex, PLOT_DRAW_BEGIN, length);
    PlotIndexSetString(hhBufferIndex, PLOT_LABEL, hhBufferLabel);

    //
    // LL Buffer ...
    string llBufferLabel = ShortName + " LL " + "(" + (string)length + ")";
    ArraySetAsSeries(llBuffer, true);
    SetIndexBuffer(llBufferIndex, llBuffer, INDICATOR_DATA);
    PlotIndexSetInteger(llBufferIndex, PLOT_DRAW_BEGIN, length);
    PlotIndexSetString(llBufferIndex, PLOT_LABEL, llBufferLabel);

    //
    // Signal Buffer ...
    string signalBufferLabel = ShortName + " S " + "(" + (string)length + ")";
    ArraySetAsSeries(signalBuffer, true);
    SetIndexBuffer(signalBufferIndex, signalBuffer, INDICATOR_DATA);
    PlotIndexSetInteger(signalBufferIndex, PLOT_DRAW_BEGIN, length);
    PlotIndexSetString(signalBufferIndex, PLOT_LABEL, signalBufferLabel);
}

//
// Set Indicator Short Name and also we can define Buffers Labels ...
void SetIndicatorName()
{
    //
    string indicatorShortName = "";
    StringConcatenate(indicatorShortName, ShortName, "");

    //
    IndicatorSetString(INDICATOR_SHORTNAME, indicatorShortName);
}

//
// Calculate Buffers ...
void CalculateBuffers(
    int bar_index // Selected Bar Index
)
{
    //
    // Calculate Threshold ...
    //
    // HH Buffer ...
    int hhIndex = iHighest(
        _Symbol,
        _Period,
        hhMode,
        length,
        bar_index);
    double hhValue = GetAppliedPrice(
        hhIndex,
        hhMode);

    //
    hhBuffer[bar_index] = hhValue;

    //
    // LL Buffer ...
    int llIndex = iLowest(
        _Symbol,
        _Period,
        llMode,
        length,
        bar_index);
    double llValue = GetAppliedPrice(
        llIndex,
        llMode);

    //
    llBuffer[bar_index] = llValue;

    //
    XOHCL c = GetCandle(bar_index);
    double lhDiff = hhValue - llValue;
    double signalValue = (lhDiff / 2);

    //
    signalBuffer[bar_index] = (hhValue - signalValue);
}
//
// END Functions ...
//