///////////////////////////////////////////////////////
//
// SaherElm IT Center MQL5 XAMA Indicator
// ---------------------------------------------
// Name: XAMA
// Description: Trend Magic Indicator ...
//
//
// Maintainer:
// ------------
// Hadi Khazaee Asl (hadi_khazaee_asl@yahoo.com)
//
//////////////////////////////////////////////////////
//
// Global Properties ...
#property copyright "Copyright 2023, SaherElm IT Center"
#property link "https://saherelm.ir"
#property version "1.00"
#property description "SaherElm XAMA Indicator"
#property strict

//
// START Constants ...
//
#define ShortName "XAMA"

//
// XAMA Indicator States ...
enum ENUM_X_XAMA_STATES
{
    X_XAMA_BULLISH = 1,
    X_XAMA_BEARISH = -1,
    X_XAMA_NEUTURAL = 0,
};
//
// END Constants ...
//

//
// START Inputs ...
//
input int length = 18;                            // Period
input int fastEMA = 2;                            // Fast EMA Period
input int slowEMA = 30;                           // Slow EMA Period
input int maShift = 0;                            // Shift
input ENUM_APPLIED_PRICE appliedTo = PRICE_CLOSE; // Applied To
//
// END Inputs ...
//

//
// Includes Logging Library ...
#include "../Libraries/x-saherelm.log.lib.mq5"

//
// Includes Common Library ...
#include "../Libraries/x-saherelm.common.lib.mq5"

//
// START Buffers ...
//
#property indicator_chart_window

//
#property indicator_buffers 3
#property indicator_plots 1

//
// maBuffer ...
#define maBufferIndex 0
#define maColorBufferIndex 1
#define stateBufferIndex 2

double maBuffer[];
double maColorBuffer[];
double stateBuffer[];

#property indicator_label1 "XAMA"
#property indicator_type1 DRAW_COLOR_LINE
#property indicator_color1 clrLime, clrGray, clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//
// END Buffers ...
//

//
// START Global Definitions: Variables, Properties and etc ...
//
int maHandler = INVALID_HANDLE;
//
// END Global Definitions: Variables, Properties and etc ...
//

//
// START Event Handlers ...
//
//
// Initialization ...
int OnInit()
{
    //
    // Validate Inputs ...
    if (!ValidateInputs())
    {
        return INIT_PARAMETERS_INCORRECT;
    }

    //
    logTag = ShortName;

    //
    // Initializing MA Handler ...
    maHandler = iAMA(
        _Symbol,
        _Period,
        length,
        fastEMA,
        slowEMA,
        maShift,
        appliedTo);
    if (maHandler == INVALID_HANDLE)
    {
        //
        string message = "Error Initializing Ma Handler ...";
        LogMessage(message);

        //
        return INIT_FAILED;
    }

    //
    // Define Index Buffers ...
    DefineBuffers();

    //
    // Set Indicator ShortName ...
    SetIndicatorName();

    //
    // Init Succeed ...
    return INIT_SUCCEEDED;
}

//
// DeInitialization ...
void OnDeinit(const int reason)
{
    //
    // REASON_PROGRAM 0 The EA has stopped working calling the ExpertRemove() function
    // REASON_REMOVE 1 Program removed from a chart
    // REASON_RECOMPILE 2 Program recompiled
    // REASON_CHARTCHANGE 3 A symbol or a chart period is changed
    // REASON_CHARTCLOSE 4 Chart closed
    // REASON_PARAMETERS 5 Inputs changed by a user
    // REASON_ACCOUNT 6 Another account has been activated or reconnection to the trade server has occurred due to changes in the account settings
    // REASON_TEMPLATE 7 Another chart template applied
    // REASON_INITFAILED 8 The OnInit() handler returned a non-zero value
    // REASON_CLOSE 9 Terminal closed

    //
    // Here we can handle De Initialization Reasons ...
    IndicatorRelease(maHandler);
}

//
// Calculations ...
//
// Calculating what we want ...
int OnCalculate(
    //
    // total Candles on chart ...
    const int rates_total,
    //
    // total calculated Candles on charts ...
    const int prev_calculated,
    //
    // history of Candles Open Time ...
    const datetime &time[],
    //
    // history of Candles Open Price ...
    const double &open[],
    //
    // history of Candles High Price ...
    const double &high[],
    //
    // history of Candles Low Price ...
    const double &low[],
    //
    // history of Candles Close Price ...
    const double &close[],
    //
    // history of Tick Volumes on Candle ...
    const long &tick_volume[],
    //
    // history of Trade Volumes ...
    const long &volume[],
    //
    // history of Candles Spread Price ...
    const int &spread[])
{
    //
    // Prepare Buffers ...
    ArraySetAsSeries(time, true);
    ArraySetAsSeries(open, true);
    ArraySetAsSeries(high, true);
    ArraySetAsSeries(low, true);
    ArraySetAsSeries(close, true);
    ArraySetAsSeries(tick_volume, true);
    ArraySetAsSeries(volume, true);
    ArraySetAsSeries(spread, true);

    //
    // this counts Available Bars ...
    int limit;

    //
    // because in some cases we may have more than one input for
    // calculation and we must prevent any calculation
    // untill we pass the biggest input length, here we get max Input length
    // and then wait until pass it ...
    int maxLength = MathMax(fastEMA, slowEMA);
    maxLength = MathMax(maxLength, length);

    //
    // Check Calculated Bars ...
    int maCalculatedBars = BarsCalculated(maHandler);
    if (maCalculatedBars < maxLength)
    {
        return prev_calculated;
    }

    //
    limit = (prev_calculated > rates_total || prev_calculated <= 0) ? rates_total : (rates_total - prev_calculated) + 1;

    //
    // Buffers Copy ...
    int copiedMas = CopyBuffer(maHandler, 0, 0, limit, maBuffer);
    if (copiedMas <= 0)
    {
        return prev_calculated;
    }

    //
    // Main Loop ...
    for (int i = limit - 1; i >= 0 && !IsStopped(); i--)
    {
        //
        // Do Buffers Calculation ...
        CalculateBuffers(i);
    }

    //
    return rates_total;
}
//
// END Event Handlers ...
//

//
// START Functions ...
//
//
// Validate Input Args for Initialization ...
bool ValidateInputs()
{
    //
    bool result = false;

    //
    // Validate Args ...
    if (length >= 2)
    {
        result = true;
    }

    //
    return result;
}

//
// Define Indexes and Styles ...
void DefineBuffers()
{
    //
    string maBufferLabel = "XAMA " + "(" + (string)length + ")";

    //
    // Ma Buffer ...
    ArraySetAsSeries(maBuffer, true);
    SetIndexBuffer(maBufferIndex, maBuffer, INDICATOR_DATA);
    PlotIndexSetString(maBufferIndex, PLOT_LABEL, maBufferLabel);

    //
    // Ma Color Buffer ...
    ArraySetAsSeries(maColorBuffer, true);
    SetIndexBuffer(maColorBufferIndex, maColorBuffer, INDICATOR_COLOR_INDEX);

    //
    // State Buffer ...
    ArraySetAsSeries(stateBuffer, true);
    SetIndexBuffer(stateBufferIndex, stateBuffer, INDICATOR_CALCULATIONS);
}

//
// Set Indicator Short Name and also we can define Buffers Labels ...
void SetIndicatorName()
{
    //
    string indicatorShortName = "";
    StringConcatenate(indicatorShortName, ShortName, " ", "(", length, ")");

    //
    IndicatorSetString(INDICATOR_SHORTNAME, indicatorShortName);
}

//
// Calculate Buffers ...
void CalculateBuffers(int bar_index)
{
    //
    // Requirements ...
    XOHCL candle = GetCandle(bar_index);

    //
    double maValue = maBuffer[bar_index];

    //
    double lineColorIndex =
        maValue < candle.low ? 0 : maValue > candle.high ? 2
                                                         : 1;

    //
    // Define State Value ...
    // lineColorIndex == 0 => Bullish => 1;
    // lineColorIndex == 1 => Neutural => 0;
    // lineColorIndex == 2 => Bearish => -1;
    double stateValue =
        lineColorIndex == 0 ? X_XAMA_BULLISH : lineColorIndex == 2 ? X_XAMA_BEARISH
                                                                   : X_XAMA_NEUTURAL;

    //
    // Set Ma Buffer Color Index ...
    maColorBuffer[bar_index] = lineColorIndex;

    //
    // Set State Buffer Value ...
    stateBuffer[bar_index] = stateValue;
}

//
// END Functions ...
//