Initial Commit ...

2024-01-25 04:03:36 +03:30
commit 0a19e0f4e1
217 changed files with 41677 additions and 0 deletions
@@ -0,0 +1,91 @@
+//+------------------------------------------------------------------+
+//|                                                         OsMA.mq4 |
+//|                   Copyright 2005-2014, MetaQuotes Software Corp. |
+//|                                              http://www.mql4.com |
+//+------------------------------------------------------------------+
+#property copyright   "2005-2014, MetaQuotes Software Corp."
+#property link        "http://www.mql4.com"
+#property description "Moving Averages of Oscillator"
+#property strict
+
+#include <MovingAverages.mqh>
+
+//--- indicator settings
+#property  indicator_separate_window
+#property  indicator_buffers 1
+#property  indicator_color1  Silver
+#property  indicator_width1  2
+//--- indicator parameters
+input int InpFastEMA=12;   // Fast EMA Period
+input int InpSlowEMA=26;   // Slow EMA Period
+input int InpSignalSMA=9;  // Signal SMA Period
+//--- indicator buffers
+double ExtOsmaBuffer[];
+double ExtMacdBuffer[];
+double ExtSignalBuffer[];
+//--- right input parameters flag
+bool   ExtParameters=false;
+//+------------------------------------------------------------------+
+//| Custom indicator initialization function                         |
+//+------------------------------------------------------------------+
+int OnInit(void)
+  {
+//--- 2 additional buffers are used for counting.
+   IndicatorBuffers(3);
+//--- drawing settings
+   SetIndexStyle(0,DRAW_HISTOGRAM);
+   SetIndexDrawBegin(0,InpSignalSMA);
+   IndicatorDigits(Digits+2);
+//--- 3 indicator buffers mapping
+   SetIndexBuffer(0,ExtOsmaBuffer);
+   SetIndexBuffer(1,ExtMacdBuffer);
+   SetIndexBuffer(2,ExtSignalBuffer);
+//--- name for DataWindow and indicator subwindow label
+   IndicatorShortName("OsMA("+IntegerToString(InpFastEMA)+","+IntegerToString(InpSlowEMA)+","+IntegerToString(InpSignalSMA)+")");
+//--- check for input parameters
+   if(InpFastEMA<=1 || InpSlowEMA<=1 || InpSignalSMA<=1 || InpFastEMA>=InpSlowEMA)
+     {
+      Print("Wrong input parameters");
+      ExtParameters=false;
+      return(INIT_FAILED);
+     }
+   else
+      ExtParameters=true;
+//--- initialization done
+   return(INIT_SUCCEEDED);
+  }
+//+------------------------------------------------------------------+
+//| Moving Average of Oscillator                                     |
+//+------------------------------------------------------------------+
+int OnCalculate (const int rates_total,
+                 const int prev_calculated,
+                 const datetime& time[],
+                 const double& open[],
+                 const double& high[],
+                 const double& low[],
+                 const double& close[],
+                 const long& tick_volume[],
+                 const long& volume[],
+                 const int& spread[])
+  {
+   int i,limit;
+//---
+   if(rates_total<=InpSignalSMA || !ExtParameters)
+      return(0);
+//--- last counted bar will be recounted
+   limit=rates_total-prev_calculated;
+   if(prev_calculated>0)
+      limit++;
+//--- macd counted in the 1-st buffer
+   for(i=0; i<limit; i++)
+      ExtMacdBuffer[i]=iMA(NULL,0,InpFastEMA,0,MODE_EMA,PRICE_CLOSE,i)-
+                    iMA(NULL,0,InpSlowEMA,0,MODE_EMA,PRICE_CLOSE,i);
+//--- signal line counted in the 2-nd buffer
+   SimpleMAOnBuffer(rates_total,prev_calculated,0,InpSignalSMA,ExtMacdBuffer,ExtSignalBuffer);
+//--- main loop
+   for(i=0; i<limit; i++)
+      ExtOsmaBuffer[i]=ExtMacdBuffer[i]-ExtSignalBuffer[i];
+//--- done
+   return(0);
+  }
+//+------------------------------------------------------------------+