saherelm/MQL5Data
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity
Files
c6e3c78e06d761781a62e1a49c0431302f01a1ca
MQL5Data/Indicators/x-saherelm.x121.xca.mq5
T
saherelm c6e3c78e06 last ...
2025-04-17 01:46:46 +03:30

2079 lines
45 KiB
Plaintext
Raw Blame History

///////////////////////////////////////////////////////
//
// SaherElm IT Center MQL5 Indicator
// -------------------------------------------------
// Name: X121 XCA
// Description: XCA ...
//
//
// Maintainer:
// ------------
// Hadi Khazaee Asl (hadi_khazaee_asl@yahoo.com)
//
//////////////////////////////////////////////////////
//
// Global Properties ...
#property copyright "Copyright 2023, SaherElm IT Center"
#property link "https://saherelm.ir"
#property version "1.00"
#property description "SaherElm X121 XCA Indicator"
#property strict
//
// Definitions ...
//
#define ShortName "X121 XCA"
//
// Includes Common Library ...
#include "../Libraries/x-saherelm.common.lib.mq5"
//
// Inputs ...
//
input group "Market";
//
input group "Short";
input ENUM_X_PERIOD_METHOD scMethod = X_PERIOD_AUTO; // How to Find Period
input ENUM_TIMEFRAMES scPeriod = NULL; // Time Period
//
input group "Medium";
input ENUM_X_PERIOD_METHOD mcMethod = X_PERIOD_AUTO; // How to Find Period
input ENUM_TIMEFRAMES mcPeriod = NULL; // Time Period
//
input group "Long";
input ENUM_X_PERIOD_METHOD lcMethod = X_PERIOD_AUTO; // How to Find Period
input ENUM_TIMEFRAMES lcPeriod = NULL; // Time Period
//
input group "Hind";
input ENUM_X_PERIOD_METHOD hcMethod = X_PERIOD_AUTO; // How to Find Period
input ENUM_TIMEFRAMES hcPeriod = NULL; // Time Period
//
input group "Boundary Detection";
input ENUM_SERIESMODE hhMode = MODE_HIGH; // Highest High Calculation Method
input ENUM_SERIESMODE llMode = MODE_LOW; // Lowest Low Calculation Method
//
input group "Fibo Levels";
input ENUM_X_FIBO_LEVELS fiboLevel1 = X_FIBO_LEVEL_236; // Fibo Level 1
input ENUM_X_FIBO_LEVELS fiboLevel2 = X_FIBO_LEVEL_500; // Fibo Level 2
input ENUM_X_FIBO_LEVELS fiboLevel3 = X_FIBO_LEVEL_764; // Fibo Level 3
//
input group "Sar Detection";
input double sarStep = 0.02; // Step
input double sarMax = 0.2; // Maximum
//
// KI ...
input group "KI";
input int kiLength = 26; // KI Length
//
input group "Swing Detection";
input int swingLength = 5; // Length
//
input group "Support and Resistance";
input int supResSmoothingLength = 7; // Smoothing Length
input ENUM_X_MA_METHOD supResSmoothingMode = X_MA_MODE_SMA; // Smoothing Method
//
// Presentation ...
input group "Presentation";
//
input int startCalculationForLastBars = 1000; // Calculate Last n Bars
//
input bool showSar = true; // Show Sar
input bool showKI = true; // Show KI
input bool showTKI = true; // Show KI Trend
input bool showTrend = true; // Show Trend
input bool showSwings = true; // Show Swings
input bool showFiboLevel1 = true; // Show Fibo Level 1
input bool showFiboLevel2 = true; // Show Fibo Level 2
input bool showFiboLevel3 = true; // Show Fibo Level 3
input bool showPeaksAndVales = true; // Show Peaks And Vales
input bool showPeakAndValeGolden = true; // Show Peak and Vale Golden
input bool showSupportAndResistance = true; // Show Support and Resistance
input bool showShortCycle = true; // Show Short Cycle
input bool showMediumCycle = true; // Show Medium Cycle
input bool showLongCycle = true; // Show Long Cycle
input bool showHindCycle = true; // Show Hind Cycle
//
input int sarArrowCode = 159; // Parabolic Sar Arrow Code
input int peakArrowCode = 159; // Peaks Arrow Code
input int valeArrowCode = 159; // Vales Arrow Code
input int swingLowArrowCode = 225; // Swing Low Arrow Code
input int swingHighArrowCode = 226; // Swing High Arrow Code
//
// Buffers ...
//
#define hideColorIDX 0
#define bullishColorIDX 1
#define bearishColorIDX 2
#define neuturalColorIDX 3
//
#define bullishState 1
#define neuturalState 0
#define bearishState -1
//
#define emptyValue 0.0
//
#property indicator_chart_window
//
#property indicator_buffers 31
#property indicator_plots 23
//
// Plot Buffers ...
//
// SHORT ...
//
#define sHHBufferIndex 0
double sHHBuffer[];
//
#property indicator_label1 "SH"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrGray
#property indicator_style1 STYLE_DOT
#property indicator_width1 1
//
#define sLLBufferIndex 1
double sLLBuffer[];
//
#property indicator_label2 "SL"
#property indicator_type2 DRAW_LINE
#property indicator_color2 clrGray
#property indicator_style2 STYLE_DOT
#property indicator_width2 1
//
// MEDIUM ...
//
#define mHHBufferIndex 2
double mHHBuffer[];
//
#property indicator_label3 "MH"
#property indicator_type3 DRAW_LINE
#property indicator_color3 clrIndigo
#property indicator_style3 STYLE_DOT
#property indicator_width3 1
//
#define mLLBufferIndex 3
double mLLBuffer[];
//
#property indicator_label4 "ML"
#property indicator_type4 DRAW_LINE
#property indicator_color4 clrIndigo
#property indicator_style4 STYLE_DOT
#property indicator_width4 1
//
// LONG ...
//
#define lHHBufferIndex 4
double lHHBuffer[];
//
#property indicator_label5 "LH"
#property indicator_type5 DRAW_LINE
#property indicator_color5 clrGoldenrod
#property indicator_style5 STYLE_DOT
#property indicator_width5 1
//
#define lLLBufferIndex 5
double lLLBuffer[];
//
#property indicator_label6 "LL"
#property indicator_type6 DRAW_LINE
#property indicator_color6 clrGoldenrod
#property indicator_style6 STYLE_DOT
#property indicator_width6 1
//
// HIND ...
//
#define hHHBufferIndex 6
double hHHBuffer[];
//
#property indicator_label7 "HH"
#property indicator_type7 DRAW_LINE
#property indicator_color7 clrBrown
#property indicator_style7 STYLE_DOT
#property indicator_width7 1
//
#define hLLBufferIndex 7
double hLLBuffer[];
//
#property indicator_label8 "HL"
#property indicator_type8 DRAW_LINE
#property indicator_color8 clrBrown
#property indicator_style8 STYLE_DOT
#property indicator_width8 1
//
// SUPPORT ...
//
#define supportBufferIndex 8
double supportBuffer[];
//
#property indicator_label9 "SUPPORT"
#property indicator_type9 DRAW_LINE
#property indicator_color9 clrLime
#property indicator_style9 STYLE_SOLID
#property indicator_width9 1
//
// RESISTANCE ...
//
#define resistanceBufferIndex 9
double resistanceBuffer[];
//
#property indicator_label10 "RESISTANCE"
#property indicator_type10 DRAW_LINE
#property indicator_color10 clrRed
#property indicator_style10 STYLE_SOLID
#property indicator_width10 1
//
// PEAKS ...
//
#define peakBufferIndex 10
double peakBuffer[];
//
#property indicator_label11 "PEAK"
#property indicator_type11 DRAW_ARROW
#property indicator_color11 clrMagenta
#property indicator_width11 1
//
// PEAKS Golden ...
//
#define peakGoldenBufferIndex 11
double peakGoldenBuffer[];
//
#property indicator_label12 "PEAK Golden"
#property indicator_type12 DRAW_LINE
#property indicator_color12 clrMagenta
#property indicator_style2 STYLE_DOT
#property indicator_width12 1
//
// VALES ...
//
#define valeBufferIndex 12
double valeBuffer[];
//
#property indicator_label13 "VALE"
#property indicator_type13 DRAW_ARROW
#property indicator_color13 clrAqua
#property indicator_width13 1
//
// VALE Golden ...
//
#define valeGoldenBufferIndex 13
double valeGoldenBuffer[];
//
#property indicator_label14 "VALES Golden"
#property indicator_type14 DRAW_LINE
#property indicator_color14 clrAqua
#property indicator_style4 STYLE_DOT
#property indicator_width14 1
//
// FIBO Level 1
//
#define fiboLevel1BufferIndex 14
double fiboLevel1Buffer[];
//
#property indicator_label15 "Fibo L1"
#property indicator_type15 DRAW_LINE
#property indicator_color15 clrGold
#property indicator_style15 STYLE_DOT
#property indicator_width15 1
//
// FIBO Level 2
//
#define fiboLevel2BufferIndex 15
double fiboLevel2Buffer[];
//
#property indicator_label16 "Fibo L2"
#property indicator_type16 DRAW_LINE
#property indicator_color16 clrYellow
#property indicator_style16 STYLE_DASH
#property indicator_width16 1
//
// FIBO Level 3
//
#define fiboLevel3BufferIndex 16
double fiboLevel3Buffer[];
//
#property indicator_label17 "Fibo L3"
#property indicator_type17 DRAW_LINE
#property indicator_color17 clrGold
#property indicator_style17 STYLE_DOT
#property indicator_width17 1
//
// SAR ...
//
#define sarBufferIndex 17
double sarBuffer[];
//
#property indicator_label18 "SAR"
#property indicator_type18 DRAW_ARROW
#property indicator_color18 clrYellow
#property indicator_width18 1
//
// TREND ...
//
#define trendBufferIndex 18
#define trendBufferPlotIndex 18
double trendBuffer[];
//
#define trendColorBufferIndex 19
double trendColorBuffer[];
//
#property indicator_label19 "TRND"
#property indicator_type19 DRAW_COLOR_LINE
#property indicator_color19 CLR_NONE, clrAqua, clrMagenta, clrGray
#property indicator_style19 STYLE_DASH
#property indicator_width19 2
//
// KI ...
//
#define kiBufferIndex 20
#define kiBufferPlotIndex 19
double kiBuffer[];
//
#define kiColorBufferIndex 21
double kiColorBuffer[];
//
#property indicator_label20 "KI"
#property indicator_type20 DRAW_COLOR_LINE
#property indicator_color20 CLR_NONE, clrGreen, clrRed, clrGray
#property indicator_style20 STYLE_DASHDOTDOT
#property indicator_width20 2
//
// SWING Low ...
//
#define swingLowBufferIndex 22
#define swingLowBufferPlotIndex 20
double swingLowBuffer[];
//
#property indicator_label21 "SWL"
#property indicator_type21 DRAW_ARROW
#property indicator_color21 clrGreen
#property indicator_width21 1
//
// SWING High ...
//
#define swingHighBufferIndex 23
#define swingHighBufferPlotIndex 21
double swingHighBuffer[];
//
#property indicator_label22 "SWH"
#property indicator_type22 DRAW_ARROW
#property indicator_color22 clrRed
#property indicator_width22 1
//
// TKI ...
//
#define tkiBufferIndex 24
#define tkiBufferPlotIndex 22
double tkiBuffer[];
//
#define tkiColorBufferIndex 25
double tkiColorBuffer[];
//
#property indicator_label23 "TKI"
#property indicator_type23 DRAW_COLOR_LINE
#property indicator_color23 CLR_NONE, clrGreen, clrRed, clrGray
#property indicator_style23 STYLE_DASHDOTDOT
#property indicator_width23 2
//
// Data Buffers ...
#define mLastBufferIndex 25
//
#define trendStateBufferIndex mLastBufferIndex + 1
double trendStateBuffer[];
//
#define kiStateBufferIndex mLastBufferIndex + 2
double kiStateBuffer[];
//
#define supBufferIndex mLastBufferIndex + 3
double supBuffer[];
//
#define resBufferIndex mLastBufferIndex + 4
double resBuffer[];
//
#define tkiStateBufferIndex mLastBufferIndex + 5
double tkiStateBuffer[];
//
// Variables, Properties and etc ...
//
// this counts Available Bars ...
int limit;
//
int maxLength;
//
// SAR Handler ...
int sarHandler = INVALID_HANDLE;
//
// TREND Handler ...
int tkiHandler = INVALID_HANDLE;
int trendHandler = INVALID_HANDLE;
//
// XMarketCycle sc;
int mSCLength = 0;
ENUM_TIMEFRAMES mSCPeriod = NULL;
//
// XMarketCycle mc;
int mMCLength = 0;
ENUM_TIMEFRAMES mMCPeriod = NULL;
//
// XMarketCycle lc;
int mLCLength = 0;
ENUM_TIMEFRAMES mLCPeriod = NULL;
//
// XMarketCycle hc;
int mHCLength = 0;
ENUM_TIMEFRAMES mHCPeriod = NULL;
//
// Event Handlers ...
/**
* Initialize Indicator ...
*
* @return ( int )
*/
int OnInit()
{
//
// Validate Inputs ...
if (!ValidateInputs())
{
return INIT_PARAMETERS_INCORRECT;
}
//
if (!InitMarketCycles())
{
return INIT_PARAMETERS_INCORRECT;
}
//
// Initialize Indicator Handlers ...
//
// SAR ...
sarHandler = iSAR(
_Symbol,
_Period,
sarStep,
sarMax //
);
bool isInited = sarHandler != INVALID_HANDLE;
if (!isInited)
{
return INIT_FAILED;
}
//
// TKI ...
tkiHandler = iMA(
_Symbol,
_Period,
kiLength,
0,
MODE_SMA,
PRICE_MEDIAN //
);
isInited = tkiHandler != INVALID_HANDLE;
if (!isInited)
{
return INIT_FAILED;
}
//
// TREND ...
trendHandler = iMA(
_Symbol,
_Period,
mHCLength,
0,
MODE_EMA,
PRICE_CLOSE //
);
isInited = trendHandler != INVALID_HANDLE;
if (!isInited)
{
return INIT_FAILED;
}
//
// because in some cases we may have more than one input for
// calculation and we must prevent any calculation
// untill we pass the biggest input length, here we get max Input length
// and then wait until pass it ...
maxLength = ExtractMaxLengthOfInputs();
//
// Define Index Buffers ...
DefineBuffers();
//
// Set Indicator ShortName ...
SetIndicatorName();
//
// Init Succeed ...
return INIT_SUCCEEDED;
}
/**
* De Initialize Indicator ...
*
* @param reason: Integer, De Initialization Reason ...
*/
void OnDeinit(const int reason)
{
//
// REASON_PROGRAM 0 The EA has stopped working calling the ExpertRemove() function
// REASON_REMOVE 1 Program removed from a chart
// REASON_RECOMPILE 2 Program recompiled
// REASON_CHARTCHANGE 3 A symbol or a chart period is changed
// REASON_CHARTCLOSE 4 Chart closed
// REASON_PARAMETERS 5 Inputs changed by a user
// REASON_ACCOUNT 6 Another account has been activated or reconnection to the trade server has occurred due to changes in the account settings
// REASON_TEMPLATE 7 Another chart template applied
// REASON_INITFAILED 8 The OnInit() handler returned a non-zero value
// REASON_CLOSE 9 Terminal closed
//
IndicatorRelease(sarHandler);
IndicatorRelease(trendHandler);
}
/**
* Calculate Bars ...
*
* @param rates_total: Integer, Total Bars on Chart ...
* @param prev_calculated: Integer, Total Calculated Bars on Charts ...
* @param time: DateTime Array, History of Open Time ...
* @param open: Double Array, History of Open Prices ...
* @param high: Double Array, History of High Prices ...
* @param low: Double Array, History of Low Prices ...
* @param close: Double Array, History of Close Prices ...
* @param tick_volume: Long, History of Tick Volumes on Bar ...
* @param volume: Long, History of Trade Volumes ...
* @param spread: Double, History of Spread Price ...
*
* @return ( int )
*/
int OnCalculate(
const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[] //
)
{
//
// Prepare Buffers ...
ArraySetAsSeries(time, true);
ArraySetAsSeries(open, true);
ArraySetAsSeries(high, true);
ArraySetAsSeries(low, true);
ArraySetAsSeries(close, true);
ArraySetAsSeries(tick_volume, true);
ArraySetAsSeries(volume, true);
ArraySetAsSeries(spread, true);
//
// Validate Calculated Bars ...
//
// SAR ...
int sarCalculatedBars = BarsCalculated(sarHandler);
//
// TKI ...
int tkiCalculatedBars = BarsCalculated(tkiHandler);
//
// TREND ...
int trendCalculatedBars = BarsCalculated(trendHandler);
//
bool isPassedRequiredCalculatedBars =
//
// SAR ...
sarCalculatedBars >= maxLength &&
//
// TKI ...
tkiCalculatedBars >= maxLength &&
//
// TREND ...
trendCalculatedBars >= maxLength
//
;
if (!isPassedRequiredCalculatedBars)
{
return prev_calculated;
}
//
limit = (prev_calculated > rates_total || prev_calculated <= 0)
? rates_total
: (rates_total - prev_calculated) + 1;
//
// Buffers Copy ...
//
// SAR ...
int copiedSars = CopyBuffer(sarHandler, 0, 0, limit, sarBuffer);
//
// TKI ...
int copiedTKIs = CopyBuffer(tkiHandler, 0, 0, limit, tkiBuffer);
//
// TREND ...
int copiedTrends = CopyBuffer(trendHandler, MAIN_LINE, 0, limit + 1, trendBuffer);
//
// Validate Copied Items ...
bool isPassedRequiredCopiedItems =
//
// SAR ...
copiedSars >= limit &&
//
// TKI ...
copiedTKIs >= limit &&
//
// TREND ...
copiedTrends >= limit
//
;
if (!isPassedRequiredCopiedItems)
{
return prev_calculated;
}
//
// Main Loop ...
for (int i = limit - 1; i >= 0 && !IsStopped(); i--)
{
//
CalculateBuffers(
i,
prev_calculated,
rates_total,
//
open,
high,
close,
low,
tick_volume //
);
}
//
return rates_total;
}
//
// Functions ...
/**
* Validate Input Args for Initialization ...
*
* @return ( bool )
*/
bool ValidateInputs()
{
//
bool result = false;
//
result =
//
// SAR ...
sarMax > 0 &&
sarStep > 0 &&
kiLength > 0 &&
swingLength > 0 &&
sarMax > sarStep &&
//
// XCA ...
(IsValid(scMethod, scPeriod) &&
IsValid(mcMethod, mcPeriod) &&
IsValid(lcMethod, lcPeriod) &&
IsValid(hcMethod, hcPeriod))
//
;
//
return result;
}
/**
* Extract Max Length of Inputs ...
*
* @return ( int )
*/
int ExtractMaxLengthOfInputs()
{
//
int result = 0;
//
result = MathMax(kiLength, swingLength);
//
return result;
}
/**
* Define Required Buffers ...
*/
void DefineBuffers()
{
//
// Plot Buffers ...
//
// SHORT ...
//
ENUM_DRAW_TYPE sDrawType = showShortCycle ? DRAW_LINE : DRAW_NONE;
//
// HH ...
//
ArraySetAsSeries(sHHBuffer, true);
SetIndexBuffer(sHHBufferIndex, sHHBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(sHHBufferIndex, PLOT_SHOW_DATA, showShortCycle);
PlotIndexSetInteger(sHHBufferIndex, PLOT_DRAW_TYPE, sDrawType);
//
PlotIndexSetDouble(sHHBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// LL ...
//
ArraySetAsSeries(sLLBuffer, true);
SetIndexBuffer(sLLBufferIndex, sLLBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(sLLBufferIndex, PLOT_SHOW_DATA, showShortCycle);
PlotIndexSetInteger(sLLBufferIndex, PLOT_DRAW_TYPE, sDrawType);
//
PlotIndexSetDouble(sLLBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// MEDIUM ...
//
ENUM_DRAW_TYPE mDrawType = showMediumCycle ? DRAW_LINE : DRAW_NONE;
//
// HH ...
//
ArraySetAsSeries(mHHBuffer, true);
SetIndexBuffer(mHHBufferIndex, mHHBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(mHHBufferIndex, PLOT_SHOW_DATA, showMediumCycle);
PlotIndexSetInteger(mHHBufferIndex, PLOT_DRAW_TYPE, mDrawType);
//
PlotIndexSetDouble(mHHBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// LL ...
//
ArraySetAsSeries(mLLBuffer, true);
SetIndexBuffer(mLLBufferIndex, mLLBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(mLLBufferIndex, PLOT_SHOW_DATA, showMediumCycle);
PlotIndexSetInteger(mLLBufferIndex, PLOT_DRAW_TYPE, mDrawType);
//
PlotIndexSetDouble(mLLBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// LONG ...
//
ENUM_DRAW_TYPE lDrawType = showLongCycle ? DRAW_LINE : DRAW_NONE;
//
// HH ...
//
ArraySetAsSeries(lHHBuffer, true);
SetIndexBuffer(lHHBufferIndex, lHHBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(lHHBufferIndex, PLOT_SHOW_DATA, showLongCycle);
PlotIndexSetInteger(lHHBufferIndex, PLOT_DRAW_TYPE, lDrawType);
//
PlotIndexSetDouble(lHHBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// LL ...
//
ArraySetAsSeries(lLLBuffer, true);
SetIndexBuffer(lLLBufferIndex, lLLBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(lLLBufferIndex, PLOT_SHOW_DATA, showLongCycle);
PlotIndexSetInteger(lLLBufferIndex, PLOT_DRAW_TYPE, lDrawType);
//
PlotIndexSetDouble(lLLBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// HIND ...
//
ENUM_DRAW_TYPE hDrawType = showHindCycle ? DRAW_LINE : DRAW_NONE;
//
// HH ...
//
ArraySetAsSeries(hHHBuffer, true);
SetIndexBuffer(hHHBufferIndex, hHHBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(hHHBufferIndex, PLOT_SHOW_DATA, showHindCycle);
PlotIndexSetInteger(hHHBufferIndex, PLOT_DRAW_TYPE, hDrawType);
//
PlotIndexSetDouble(hHHBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// LL ...
//
ArraySetAsSeries(hLLBuffer, true);
SetIndexBuffer(hLLBufferIndex, hLLBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(hLLBufferIndex, PLOT_SHOW_DATA, showHindCycle);
PlotIndexSetInteger(hLLBufferIndex, PLOT_DRAW_TYPE, hDrawType);
//
PlotIndexSetDouble(hLLBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// SUPPORT / RESISTANCE ...
//
ENUM_DRAW_TYPE supResDrawType = showSupportAndResistance ? DRAW_LINE : DRAW_NONE;
//
// SUPPORT ...
//
ArraySetAsSeries(supportBuffer, true);
SetIndexBuffer(supportBufferIndex, supportBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(supportBufferIndex, PLOT_SHOW_DATA, showSupportAndResistance);
PlotIndexSetInteger(supportBufferIndex, PLOT_DRAW_TYPE, supResDrawType);
//
PlotIndexSetDouble(supportBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// RESISTANCE ...
//
ArraySetAsSeries(resistanceBuffer, true);
SetIndexBuffer(resistanceBufferIndex, resistanceBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(resistanceBufferIndex, PLOT_SHOW_DATA, showSupportAndResistance);
PlotIndexSetInteger(resistanceBufferIndex, PLOT_DRAW_TYPE, supResDrawType);
//
PlotIndexSetDouble(resistanceBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// PEAK / VALE ...
//
ENUM_DRAW_TYPE pvDrawType = showPeaksAndVales ? DRAW_ARROW : DRAW_NONE;
//
// PEAK ...
//
ArraySetAsSeries(peakBuffer, true);
SetIndexBuffer(peakBufferIndex, peakBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(peakBufferIndex, PLOT_SHOW_DATA, showPeaksAndVales);
PlotIndexSetInteger(peakBufferIndex, PLOT_DRAW_TYPE, pvDrawType);
//
PlotIndexSetDouble(peakBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
PlotIndexSetInteger(peakBufferIndex, PLOT_ARROW, peakArrowCode);
//
// VALE ...
//
ArraySetAsSeries(valeBuffer, true);
SetIndexBuffer(valeBufferIndex, valeBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(valeBufferIndex, PLOT_SHOW_DATA, showPeaksAndVales);
PlotIndexSetInteger(valeBufferIndex, PLOT_DRAW_TYPE, pvDrawType);
//
PlotIndexSetDouble(valeBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
PlotIndexSetInteger(valeBufferIndex, PLOT_ARROW, valeArrowCode);
//
// PV GOLDEN ...
//
ENUM_DRAW_TYPE pvGoldenDrawType = showPeakAndValeGolden ? DRAW_LINE : DRAW_NONE;
//
// PEAK Golden ...
//
ArraySetAsSeries(peakGoldenBuffer, true);
SetIndexBuffer(peakGoldenBufferIndex, peakGoldenBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(peakGoldenBufferIndex, PLOT_SHOW_DATA, showPeakAndValeGolden);
PlotIndexSetInteger(peakGoldenBufferIndex, PLOT_DRAW_TYPE, pvGoldenDrawType);
//
PlotIndexSetDouble(peakGoldenBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// VALE Golden ...
//
ArraySetAsSeries(valeGoldenBuffer, true);
SetIndexBuffer(valeGoldenBufferIndex, valeGoldenBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(valeGoldenBufferIndex, PLOT_SHOW_DATA, showPeakAndValeGolden);
PlotIndexSetInteger(valeGoldenBufferIndex, PLOT_DRAW_TYPE, pvGoldenDrawType);
//
PlotIndexSetDouble(valeGoldenBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// FIBO L1 ...
//
ENUM_DRAW_TYPE fiboL1DrawType = showFiboLevel1 ? DRAW_LINE : DRAW_NONE;
//
ArraySetAsSeries(fiboLevel1Buffer, true);
SetIndexBuffer(fiboLevel1BufferIndex, fiboLevel1Buffer, INDICATOR_DATA);
//
PlotIndexSetInteger(fiboLevel1BufferIndex, PLOT_SHOW_DATA, showFiboLevel1);
PlotIndexSetInteger(fiboLevel1BufferIndex, PLOT_DRAW_TYPE, fiboL1DrawType);
//
PlotIndexSetDouble(fiboLevel1BufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// FIBO L2 ...
//
ENUM_DRAW_TYPE fiboL2DrawType = showFiboLevel2 ? DRAW_LINE : DRAW_NONE;
//
ArraySetAsSeries(fiboLevel2Buffer, true);
SetIndexBuffer(fiboLevel2BufferIndex, fiboLevel2Buffer, INDICATOR_DATA);
//
PlotIndexSetInteger(fiboLevel2BufferIndex, PLOT_SHOW_DATA, showFiboLevel2);
PlotIndexSetInteger(fiboLevel2BufferIndex, PLOT_DRAW_TYPE, fiboL2DrawType);
//
PlotIndexSetDouble(fiboLevel2BufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// FIBO L3 ...
//
ENUM_DRAW_TYPE fiboL3DrawType = showFiboLevel3 ? DRAW_LINE : DRAW_NONE;
//
ArraySetAsSeries(fiboLevel3Buffer, true);
SetIndexBuffer(fiboLevel3BufferIndex, fiboLevel3Buffer, INDICATOR_DATA);
//
PlotIndexSetInteger(fiboLevel3BufferIndex, PLOT_SHOW_DATA, showFiboLevel3);
PlotIndexSetInteger(fiboLevel3BufferIndex, PLOT_DRAW_TYPE, fiboL3DrawType);
//
PlotIndexSetDouble(fiboLevel3BufferIndex, PLOT_EMPTY_VALUE, emptyValue);
//
// SAR ...
//
ENUM_DRAW_TYPE sarDrawType = showSar ? DRAW_ARROW : DRAW_NONE;
//
ArraySetAsSeries(sarBuffer, true);
SetIndexBuffer(sarBufferIndex, sarBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(sarBufferIndex, PLOT_SHOW_DATA, showSar);
PlotIndexSetInteger(sarBufferIndex, PLOT_DRAW_TYPE, sarDrawType);
//
PlotIndexSetDouble(sarBufferIndex, PLOT_EMPTY_VALUE, emptyValue);
PlotIndexSetInteger(sarBufferIndex, PLOT_ARROW, sarArrowCode);
//
// TREND ...
//
ENUM_DRAW_TYPE trendDrawType = showTrend ? DRAW_COLOR_LINE : DRAW_NONE;
//
ArraySetAsSeries(trendBuffer, true);
SetIndexBuffer(trendBufferIndex, trendBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(trendBufferPlotIndex, PLOT_SHOW_DATA, showTrend);
// PlotIndexSetInteger(trendBufferPlotIndex, PLOT_DRAW_TYPE, trendDrawType);
//
PlotIndexSetDouble(trendBufferPlotIndex, PLOT_EMPTY_VALUE, emptyValue);
//
ArraySetAsSeries(trendColorBuffer, true);
SetIndexBuffer(trendColorBufferIndex, trendColorBuffer, INDICATOR_COLOR_INDEX);
//
// KI ...
//
ENUM_DRAW_TYPE kiDrawType = showKI ? DRAW_COLOR_LINE : DRAW_NONE;
//
ArraySetAsSeries(kiBuffer, true);
SetIndexBuffer(kiBufferIndex, kiBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(kiBufferPlotIndex, PLOT_SHOW_DATA, showKI);
// PlotIndexSetInteger(kiBufferPlotIndex, PLOT_DRAW_TYPE, kiDrawType);
//
PlotIndexSetDouble(kiBufferPlotIndex, PLOT_EMPTY_VALUE, emptyValue);
//
ArraySetAsSeries(kiColorBuffer, true);
SetIndexBuffer(kiColorBufferIndex, kiColorBuffer, INDICATOR_COLOR_INDEX);
//
// TKI ...
//
ENUM_DRAW_TYPE tkiDrawType = showTKI ? DRAW_COLOR_LINE : DRAW_NONE;
//
ArraySetAsSeries(tkiBuffer, true);
SetIndexBuffer(tkiBufferIndex, tkiBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(tkiBufferPlotIndex, PLOT_SHOW_DATA, showKI);
// PlotIndexSetInteger(tkiBufferPlotIndex, PLOT_DRAW_TYPE, kiDrawType);
//
PlotIndexSetDouble(tkiBufferPlotIndex, PLOT_EMPTY_VALUE, emptyValue);
//
ArraySetAsSeries(tkiColorBuffer, true);
SetIndexBuffer(tkiColorBufferIndex, tkiColorBuffer, INDICATOR_COLOR_INDEX);
//
// SWINGS ...
//
ENUM_DRAW_TYPE swingDrawType = showSwings ? DRAW_ARROW : DRAW_NONE;
//
// SWING Low ...
//
ArraySetAsSeries(swingLowBuffer, true);
SetIndexBuffer(swingLowBufferIndex, swingLowBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(swingLowBufferPlotIndex, PLOT_SHOW_DATA, showSwings);
PlotIndexSetInteger(swingLowBufferPlotIndex, PLOT_DRAW_TYPE, swingDrawType);
//
PlotIndexSetDouble(swingLowBufferPlotIndex, PLOT_EMPTY_VALUE, emptyValue);
PlotIndexSetInteger(swingLowBufferPlotIndex, PLOT_ARROW, swingLowArrowCode);
//
// SWING High ...
//
ArraySetAsSeries(swingHighBuffer, true);
SetIndexBuffer(swingHighBufferIndex, swingHighBuffer, INDICATOR_DATA);
//
PlotIndexSetInteger(swingHighBufferPlotIndex, PLOT_SHOW_DATA, showSwings);
PlotIndexSetInteger(swingHighBufferPlotIndex, PLOT_DRAW_TYPE, swingDrawType);
//
PlotIndexSetDouble(swingHighBufferPlotIndex, PLOT_EMPTY_VALUE, emptyValue);
PlotIndexSetInteger(swingHighBufferPlotIndex, PLOT_ARROW, swingHighArrowCode);
//
// Data Buffers ...
//
ArraySetAsSeries(trendStateBuffer, true);
SetIndexBuffer(trendStateBufferIndex, trendStateBuffer, INDICATOR_CALCULATIONS);
//
ArraySetAsSeries(kiStateBuffer, true);
SetIndexBuffer(kiStateBufferIndex, kiStateBuffer, INDICATOR_CALCULATIONS);
//
ArraySetAsSeries(supBuffer, true);
SetIndexBuffer(supBufferIndex, supBuffer, INDICATOR_CALCULATIONS);
//
ArraySetAsSeries(resBuffer, true);
SetIndexBuffer(resBufferIndex, resBuffer, INDICATOR_CALCULATIONS);
//
ArraySetAsSeries(tkiStateBuffer, true);
SetIndexBuffer(tkiStateBufferIndex, tkiStateBuffer, INDICATOR_CALCULATIONS);
//
}
/**
* Set Indicator Short Name and also we can define Buffers Labels ...
*/
void SetIndicatorName()
{
//
IndicatorSetInteger(INDICATOR_DIGITS, _Digits);
IndicatorSetString(INDICATOR_SHORTNAME, ShortName);
}
/**
* Calculate Custom Buffers ...
*
* @param bar_index: Integer, Represent Current Bar ...
* @param prevCalculated: Integer, Represent Previous Calculated Bars ...
* @param ratesTotal: Integer, Represents All Available Bars ...
* @param open: Double Array, History of Open Prices ...
* @param high: Double Array, History of High Prices ...
* @param close: Double Array, History of Close Prices ...
* @param low: Double Array, History of Low Prices ...
* @param tickVolume: Long, History of Tick Volumes on Bar ...
*/
void CalculateBuffers(
int bar_index, // Selected Bar Index
const int prevCalculated,
const int ratesTotal,
const double &open[],
const double &high[],
const double &close[],
const double &low[],
const long &tickVolume[] //
)
{
//
int barsLimit = startCalculationForLastBars > 0
? startCalculationForLastBars
: 0;
//
// bool canCalculate = true;
bool canCalculate =
barsLimit == 0 ||
bar_index <= barsLimit;
if (canCalculate)
{
//
// Calculate Cycles ...
CalculateCycles(bar_index);
//
// Calculate Support nad Resistance ...
CalculateValues(
bar_index,
prevCalculated,
ratesTotal,
open,
high,
close,
low,
tickVolume //
);
//
int swingBarIndex = bar_index;
if (bar_index < swingLength)
{
swingBarIndex = bar_index + swingLength;
}
// //
// // Calcultae Swing High and Low and Trends ...
// CalculateSwingsAndTrend(
// swingBarIndex,
// prevCalculated,
// ratesTotal,
// open,
// high,
// close,
// low,
// tickVolume //
// );
//
if (bar_index < swingLength)
{
//
// for (int i = bar_index; i < bar_index + swingLength; i++)
// {
// //
// trendBuffer[i] = lTrend;
// swingLowsBuffer[i] = lSwingLow;
// swingHighsBuffer[i] = lSwingHigh;
// trendStateBuffer[i] = lTrendState;
// trendColorBuffer[i] = lTrendColor;
// }
}
}
else
{
FillBuffersZero(bar_index);
}
}
//
// Custom ...
/**
* Initial Market Cycles ...
*
* @return ( bool )
*/
bool InitMarketCycles()
{
//
bool result = false;
//
int cPeriodSeconds = PeriodSeconds(_Period);
//
// Find Cycle Period ...
if (scMethod == X_PERIOD_AUTO)
{
//
// Select Period ...
mSCPeriod = GetCyclePeriod(
X_MARKET_CYCLE_SHORT,
_Period //
);
}
else
{
mSCPeriod = scPeriod;
}
//
if (IsValid(mSCPeriod))
{
mSCLength = PeriodSeconds(mSCPeriod) / cPeriodSeconds;
}
//
// Find Cycle Period ...
if (mcMethod == X_PERIOD_AUTO)
{
//
// Select Period ...
mMCPeriod = GetCyclePeriod(
X_MARKET_CYCLE_MEDIUM,
_Period //
);
}
else
{
mMCPeriod = mcPeriod;
}
//
if (IsValid(mMCPeriod))
{
mMCLength = PeriodSeconds(mMCPeriod) / cPeriodSeconds;
}
//
// Find Cycle Period ...
if (lcMethod == X_PERIOD_AUTO)
{
//
// Select Period ...
mLCPeriod = GetCyclePeriod(
X_MARKET_CYCLE_LONG,
_Period //
);
}
else
{
mLCPeriod = lcPeriod;
}
//
if (IsValid(mLCPeriod))
{
mLCLength = PeriodSeconds(mLCPeriod) / cPeriodSeconds;
}
//
// Find Cycle Period ...
if (hcMethod == X_PERIOD_AUTO)
{
//
// Select Period ...
mHCPeriod = GetCyclePeriod(
X_MARKET_CYCLE_HIND,
_Period //
);
}
else
{
mHCPeriod = hcPeriod;
}
//
if (IsValid(mHCPeriod))
{
mHCLength = PeriodSeconds(mHCPeriod) / cPeriodSeconds;
}
//
result = mSCLength > 0 &&
mMCLength > mSCLength &&
mLCLength > mMCLength &&
mHCLength > mLCLength;
//
return result;
}
/**
* Fill All Bufers to Zero Vlue for Specified Bar Index ...
*
* @param barIndex: Integer ...
*/
void FillBuffersZero(int barIndex)
{
//
// SHORT ...
sHHBuffer[barIndex] = emptyValue;
sLLBuffer[barIndex] = emptyValue;
//
// MEDIUM ...
mHHBuffer[barIndex] = emptyValue;
mLLBuffer[barIndex] = emptyValue;
//
// LONG ...
lHHBuffer[barIndex] = emptyValue;
lLLBuffer[barIndex] = emptyValue;
//
// HIND ...
hHHBuffer[barIndex] = emptyValue;
hLLBuffer[barIndex] = emptyValue;
//
// SUPPORT / RESISTANCE ...
supBuffer[barIndex] = emptyValue;
resBuffer[barIndex] = emptyValue;
supportBuffer[barIndex] = emptyValue;
resistanceBuffer[barIndex] = emptyValue;
//
// PEAKS ...
peakBuffer[barIndex] = emptyValue;
peakGoldenBuffer[barIndex] = emptyValue;
//
// VALES ...
valeBuffer[barIndex] = emptyValue;
valeGoldenBuffer[barIndex] = emptyValue;
//
// SAR ...
sarBuffer[barIndex] = emptyValue;
//
// TREND ...
trendBuffer[barIndex] = emptyValue;
trendColorBuffer[barIndex] = hideColorIDX;
trendStateBuffer[barIndex] = hideColorIDX;
//
// KI ...
kiBuffer[barIndex] = emptyValue;
kiColorBuffer[barIndex] = hideColorIDX;
kiStateBuffer[barIndex] = hideColorIDX;
//
// TKI ...
tkiBuffer[barIndex] = emptyValue;
tkiColorBuffer[barIndex] = hideColorIDX;
tkiStateBuffer[barIndex] = hideColorIDX;
//
// SWINGS ...
swingLowBuffer[barIndex] = emptyValue;
swingHighBuffer[barIndex] = emptyValue;
}
/**
* Calculate Specified Market Cycle Info ...
*
* @param barIndex: Integer, Bar Index ...
* @param cycle: ENUM_X_MARKET_CYCLES member, Specified Cycle ...
* @param hhBuffer: Highest High Buffer Reference ...
* @param llBuffer: Lowest Low Buffer Reference ...
*/
void CalculateCycle(
int barIndex,
ENUM_X_MARKET_CYCLES cycle,
double &hhBuffer[],
double &llBuffer[] //
)
{
//
XOHCL bar;
bool isBarInited = bar.Init(
_Symbol,
_Period,
barIndex
//
);
if (!isBarInited)
{
return;
}
//
int mLength = 0;
switch (cycle)
{
//
case X_MARKET_CYCLE_SHORT:
mLength = mSCLength;
break;
//
case X_MARKET_CYCLE_MEDIUM:
mLength = mMCLength;
break;
//
case X_MARKET_CYCLE_LONG:
mLength = mLCLength;
break;
//
case X_MARKET_CYCLE_HIND:
mLength = mHCLength;
break;
}
//
if (mLength == 0)
{
return;
}
//
// Find Highest High ...
double hhValue = bar.FindHighest(
mLength,
hhMode
//
);
hhBuffer[barIndex] = hhValue;
//
// Find Lowest Low ...
double llValue = bar.FindLowest(
mLength,
llMode
//
);
llBuffer[barIndex] = llValue;
}
/**
* Claculate Cycles ...
*
* @param barIndex: Integer, Bar Index ...
*/
void CalculateCycles(int barIndex)
{
//
// SHORT ...
CalculateCycle(
barIndex,
X_MARKET_CYCLE_SHORT,
sHHBuffer,
sLLBuffer //
);
//
// MEDIUM ...
CalculateCycle(
barIndex,
X_MARKET_CYCLE_MEDIUM,
mHHBuffer,
mLLBuffer //
);
//
// LONG ...
CalculateCycle(
barIndex,
X_MARKET_CYCLE_LONG,
lHHBuffer,
lLLBuffer //
);
//
// HIND ...
CalculateCycle(
barIndex,
X_MARKET_CYCLE_HIND,
hHHBuffer,
hLLBuffer //
);
}
/**
* Calculate Values ...
*
* @param bar_index: int, Specified Bar Index ...
* @param prevCalculated: int, Provides Previous Calculated Bars ...
* @param ratesTotal: int, Provides All Availabled Bars ...
* @param open: double Collection, Provides Open Prices Time Series ...
* @param high: double Collection, Provides High Prices Time Series ...
* @param close: double Collection, Provides Close Prices Time Series ...
* @param low: double Collection, Provides Low Prices Time Series ...
* @param tickVolume: long Collection, Provides Ticks Volume Prices Time Series ...
*/
void CalculateValues(
int bar_index, // Selected Bar Index
const int prevCalculated,
const int ratesTotal,
const double &open[],
const double &high[],
const double &close[],
const double &low[],
const long &tickVolume[] //
)
{
//
// Check Prev Bar ...
//
int lastBarIndex = bar_index + 1;
bool isFirstBar =
startCalculationForLastBars > 0
? bar_index == startCalculationForLastBars
: bar_index == ratesTotal;
XOHCL iBar;
bool isInited = iBar.Init(
_Symbol,
_Period,
bar_index //
);
//
double iSHH = sHHBuffer[bar_index];
double iSLL = sLLBuffer[bar_index];
//
double iMHH = mHHBuffer[bar_index];
double iMLL = mLLBuffer[bar_index];
//
double iLHH = lHHBuffer[bar_index];
double iLLL = lLLBuffer[bar_index];
//
double iHHH = hHHBuffer[bar_index];
double iHLL = hLLBuffer[bar_index];
//
// Calculate BOS ...
//
// Calculate CHOCH ...
//
// Calculate Support ...
double lastSupport =
isFirstBar
? emptyValue
: supBuffer[lastBarIndex];
bool isSupport = iSLL == iMLL;
double iSupport =
isSupport
? iSLL
: lastSupport;
supBuffer[bar_index] = iSupport;
//
// Calculate Vale ...
double lastVale =
isFirstBar
? emptyValue
: valeBuffer[lastBarIndex];
bool isVale =
isSupport &&
iMLL == iLLL &&
iLLL == iHLL;
double iVale =
isVale
? iMLL
: lastVale;
valeBuffer[bar_index] = iVale;
//
// Calculate Resistance ...
double lastResistance =
isFirstBar
? emptyValue
: resBuffer[lastBarIndex];
bool isResistance = iSHH == iMHH;
double iResistance =
isResistance
? iSHH
: lastResistance;
resBuffer[bar_index] = iResistance;
//
// Calculate Peak ...
double lastPeak =
isFirstBar
? emptyValue
: peakBuffer[lastBarIndex];
bool isPeak =
isResistance &&
iMHH == iLHH &&
iLHH == iHHH;
double iPeak =
isPeak
? iMHH
: lastPeak;
peakBuffer[bar_index] = iPeak;
//
bool canSmooth =
supResSmoothingLength > 0 &&
supResSmoothingMode != X_MA_MODE_NONE;
if (!canSmooth)
{
//
supportBuffer[bar_index] = iSupport;
resistanceBuffer[bar_index] = iResistance;
}
else
{
//
// Support ...
iMAOnBuffer(
ratesTotal,
prevCalculated,
bar_index,
supResSmoothingLength,
supBuffer,
supportBuffer,
supResSmoothingMode //
);
//
// Resistance ...
iMAOnBuffer(
ratesTotal,
prevCalculated,
bar_index,
supResSmoothingLength,
resBuffer,
resistanceBuffer,
supResSmoothingMode //
);
}
//
// Calculate Fibo Levels ...
//
double iFiboUpper = peakBuffer[bar_index];
double iFiboLower = valeBuffer[bar_index];
//
double iFiboLevel1 = GetFibonacciLevel(
iFiboUpper,
iFiboLower,
fiboLevel1,
X_DIRECTION_BEARISH //
);
fiboLevel1Buffer[bar_index] = iFiboLevel1;
//
double iFiboLevel2 = GetFibonacciLevel(
iFiboUpper,
iFiboLower,
fiboLevel2,
X_DIRECTION_BEARISH //
);
fiboLevel2Buffer[bar_index] = iFiboLevel2;
//
double iFiboLevel3 = GetFibonacciLevel(
iFiboUpper,
iFiboLower,
fiboLevel3,
X_DIRECTION_BEARISH //
);
fiboLevel3Buffer[bar_index] = iFiboLevel3;
//
// Calculate Trend Color Buffer ...
double iClose = close[bar_index];
double iTrend = trendBuffer[bar_index];
//
double iTrendState = neuturalState;
double iTrendColor = neuturalColorIDX;
if (iClose > iTrend)
{
//
iTrendState = bullishState;
iTrendColor = !showTrend
? hideColorIDX
: bullishColorIDX;
}
else if (iClose < iTrend)
{
//
iTrendState = bearishState;
iTrendColor = !showTrend
? hideColorIDX
: bearishColorIDX;
}
trendStateBuffer[bar_index] = iTrendState;
trendColorBuffer[bar_index] = iTrendColor;
//
// Calculate KI / Color ...
if (isInited)
{
//
double iLLKI = iBar.FindLowest(kiLength, MODE_LOW);
double iHHKI = iBar.FindHighest(kiLength, MODE_HIGH);
//
double iKI = (iHHKI + iLLKI) / 2;
kiBuffer[bar_index] = iKI;
//
double iKIState = neuturalState;
double iKIColor = neuturalColorIDX;
if (iClose > iKI)
{
//
iKIState = bullishState;
iKIColor =
!showKI
? hideColorIDX
: bullishColorIDX;
}
else if (iClose < iKI)
{
//
iKIState = bearishState;
iKIColor =
!showKI
? hideColorIDX
: bearishColorIDX;
}
kiStateBuffer[bar_index] = iKIState;
kiColorBuffer[bar_index] = iKIColor;
}
//
// Calculate PV Gold ...
if (isInited)
{
//
double iPeakGold = iBar.FindHighest(mHCLength, MODE_CLOSE);
peakGoldenBuffer[bar_index] = iPeakGold;
//
double iValeGold = iBar.FindLowest(mHCLength, MODE_CLOSE);
valeGoldenBuffer[bar_index] = iValeGold;
}
//
// Calculate Swings ...
//
double lastSwingLow =
isFirstBar
? emptyValue
: swingLowBuffer[lastBarIndex];
bool isSwingLow = IsSwingLow(
high,
low,
bar_index,
swingLength //
);
double iSwingLow =
isSwingLow
? low[bar_index]
: lastSwingLow;
swingLowBuffer[bar_index] = iSwingLow;
//
double lastSwingHigh =
isFirstBar
? emptyValue
: swingHighBuffer[lastBarIndex];
bool isSwingHigh = IsSwingHigh(
high,
low,
bar_index,
swingLength //
);
double iSwingHigh =
isSwingHigh
? high[bar_index]
: lastSwingHigh;
swingHighBuffer[bar_index] = iSwingHigh;
//
// TKI State and Color ...
//
double iTKI = tkiBuffer[bar_index];
//
double iTKIState = neuturalState;
double iTKIColor = neuturalColorIDX;
if (iClose > iTKI)
{
//
iTKIState = bullishState;
iTKIColor =
!showTKI
? hideColorIDX
: bullishColorIDX;
}
else if (iClose < iTKI)
{
//
iTKIState = bearishState;
iTKIColor =
!showTKI
? hideColorIDX
: bearishColorIDX;
}
tkiStateBuffer[bar_index] = iTKIState;
tkiColorBuffer[bar_index] = iTKIColor;
//
// Cleanup Resources ...
//
iBar.Clean();
}
//
bool IsSwingLow(
const double &high[],
const double &low[],
int index,
int length //
)
{
//
bool result = false;
//
for (int i = index + 1; i <= index + length; i++)
{
//
result = low[index] < low[i];
if (!result)
{
break;
}
}
//
return result;
}
//
bool IsSwingHigh(
const double &high[],
const double &low[],
int index,
int length //
)
{
//
bool result = false;
//
for (int i = index + 1; i <= index + length; i++)
{
//
result = high[index] > high[i];
if (!result)
{
break;
}
}
//
return result;
}
//
Reference in New Issue View Git Blame Copy Permalink